[Zx81:Type-Ins] "Your Computer" campaign...

[XavSnap]

"Your computer" 06/82


"Zx Assault" (Assault Craft)

/Basic Game/

Keys: Q-Z-0


Contributor : XavSnap.

Code: Select all

10 LET P = 0
20 LET SC = 0
30 LET T = 3 
40 POKE 16418,0 
50 FOR A = 0 TO 19 STEP 3 
60 FOR B = 18 TO 0 STEP -2
70 PRINT AT A,B;"¸«"; AT A + 2, B;"®«"
80 NEXT B
90 PRINT AT A,26; " * "; TAB 26; " * " 
100 NEXT A 
110 FOR A = 1 TO (T-1) * 2 STEP 2
120 PRINT AT A, 28;"’‘"
130 NEXT A
140 PRINT AT 23,6;"phase‰0";AT 23,16;"score‰";SC
150 LET U = 1 
160 LET X = 0
170 LET S = 10
180 LET N = -2
190 LET N = N + 2
200 FOR A = 1 TO 8
210 LET B = INT (RND * 7) * 3+1
220 FOR C = N TO 24 STEP 2
230 PRINT AT B,C;"’‘"
240 IF X<>0 THEN GOTO 510
250 IF INKEY$="0" THEN GOTO 490
260 PRINT AT S,22;"  "
270 LET S = S + ((INKEY$ = "Z") *3) - ((INKEY$="Q") *3)
280 LET S = S + ((S = - 2) *3) - ((S=22) *3)
290 PRINT AT B,C;"  ";AT S,22;"Ž‘"
300 NEXT C
310 PRINT AT U,28;"  "
320 LET U = U + 2
330 LET T = T - 1
340 IF T = 0 THEN GOTO 700
350 NEXT A
360 FOR A = 0 TO 21
378 PRINT AT A,N;"  "
380 NEXT A 
385 PRINT AT 23, 12; N/2 
390 IF N<>12 THEN GOTO 190 
395 POKE 16418,2
400 CLS
410 PRINT AT 10, 0;"«well«done•attack«wave«defeated«"
420 PRINT "YOU GET A BONUS SHIP"
430 PRINT,,"HIT A KEY TO CONTINUE"
440 IF INKEY$ ="" THEN GOTO 440
450 CLS
460 LET T = T+ 1
470 POKE 16418,0
480 GOTO 40
490 LET X = 22
500 LET S1 = S
510 PRINT AT S1,X;" "
520 LET X = X - 2
530 IF X = N THEN GOTO 680
540 IF (X = C OR X + 2 = C) AND S1 = B THEN GOTO 570
550 PRINT AT S1,X;"-"
560 GOTO 260
570 LET X = 0
580 PRINT AT S1,C;"  "
590 LET SC = SC +(N/2) * 10 + (20 - C)
600 PRINT AT 23, 22; SC
610 IF SC > 1000 AND P=0 THEN GOTO 640
630 GOTO 350
640 POKE 16418,2
645 CLS
650 PRINT AT 10, 0;"well«done•«your«score«was««˜———"
668 LET P = 1
670 GOTO 420
680 LET X = 0 
690 GOTO 260
700 PRINT AT 10, 5; "ANOTHER GO?"
710 POKE 16418,2
720 IF INKEY$= "Y" THEN GOTO 750
730 IF INKEY$= "N" THEN STOP
740 GOTO 720
750 CLS
760 RUN  

ZXASSAULT.P

(2.6 KiB) Downloaded 117 times

[XavSnap]

"Your computer" 06/83


"Kong Jump"

/Basic Game/

Keys: 5-8 jump: Shift + 5 or 8.

Contributor : XavSnap.

Code: Select all

 70 CLS 
 80 GOSUB 430
 90 LET O=1
100 LET A=1
110 LET B=A
120 LET C=26 
130 LET S=0
140 LET K=C
150 LET L=A
160 LET N=L+L
170 LET P=C
180 LET T=L-L
 190 PRINT AT 0,26;"H";TAB 26;"H";AT PI,T;A$(O);TAB 27;\
" ––";TAB T;"³³³³³³³³³³³³³³³³³³³\
³³³³³³³³¼¯«¼¯";TAB T;"³³³³³³³³³³\
³³kong³³³³³³³³³³³ª°«º¬";TAB T;"«\
«««««««««««««««««««««««««« ¼ ¯";\
TAB 27;"·¶ ·¶"
 200 PRINT AT N,K;"H";AT N,C;"OO\
O ";AT A,B;"O";TAB B;"L" AND INK\
EY$="8";TAB B;"L" AND INKEY$=CHR\
$ 115;TAB B;"L" AND INKEY$="";TA\
B B;"J" AND INKEY$="5";TAB B;"J"\
 AND INKEY$=CHR$ 114;TAB B;"X" A\
ND INKEY$=CHR$ 112;AT A+N,B; 
210 LET E=PEEK (PEEK 16398+256*PEEK 16399)
 220 IF A=L AND B=C OR A=L AND B\
=C+N OR A=L AND B=C+N+N OR A>=N \
THEN GOTO 360
230 IF E<>128 THEN LET A=A+L 
240 LET S=S+(E=P+P)+P*(E=45)
250 IF E=45 THEN GOTO 320 
260 LET C=C-1
270 IF C=T THEN LET C=P 
280 LET B=B+(INKEY$="8" OR INKEY$=CHR$ 115)-(INKEY$="5" OR INKEY$=CHR$ 114) 
290 IF E=128 AND INKEY$>=CHR$ 112 THEN LET A=A-L
300 PRINT AT N,T;"     ";AT T,B-L;"   ";TAB B-L;"    ";TAB B-L; "   "
310 GOTO 200 
320 LET K=K+((P-L)*(K=L))-((P-L)*(K=P)) 
330 LET O=O+1 
340 IF O>10 THEN LET O=1 
350 GOTO 190 
360 PRINT AT 5,0; "score³";S 
370 PRINT AT 7,4; "GAME OVER"
380 PRINT AT 8,2; "PRESS ANY KEY TO START"
390 IF INKEY$<>"" THEN GOTO 395
 391 PRINT AT 2,27;"    ";TAB 27\
;" –– ";TAB 27;"¼¯«¼¯";TAB 27;"ª\
°«º¬";TAB 27;" ¼ ¯  ";TAB 27;"·¶\
 ·¶";TAB 27;" ª³O "
392 IF INKEY$<>"" THEN GOTO 395 
 393 PRINT AT 2,27;"¼  ¯";TAB 27\
;"ª––¬";TAB 27;" °«º ";TAB 27;" \
¼ ¯ ";TAB 27;"·¶ ·¶";TAB 27;"     " 
394 GOTO 390
395 FOR A=8 TO 20
396 PRINT AT A,27;"ª³O "; AT A-1,27;"     " 
397 NEXT A 
398 PRINT AT 18,28;"²ª";AT 19,29;"º" 
399 FOR A=0 TO 50
400 NEXT A 
410 CLS 
420 RUN
 430 DIM A$(10,27)
 440 LET A$(1)="««««« ««««« ««« \
«« ««««««««"
 450 LET A$(2)="«« « « « « « « «\
 « « « « ««"
 460 LET A$(3)="«« ««« « «« « ««\
« « « «« ««"
 470 LET A$(4)="««««««««««««««««\
«««««««««««"
 480 LET A$(5)="«« « «« ««« ««««\
 « «« ««« «"
 490 LET A$(6)="««« ««« « «« «««\
« ««««« « «"
 500 LET A$(7)="««««« «« «« « ««\
« «« ««« ««"
 510 LET A$(8)="«« «« «« «««« « \
«« «« « «««"
 520 LET A$(9)="««« « «« ««« « «\
 «« «««« ««"
 530 LET A$(10)="«««« «««« «««« \
«««« ««« ««"
540 RETURN
550 SAVE "KONG"
580 RUN 

KONGJUMP.P

(2.91 KiB) Downloaded 109 times

[XavSnap]

"Your computer" 01/83


"THE CODE MACHINE"

/Basic tool/

Contributor : Antipontifex.

Code: Select all

0 REM A  K.HART PROGRAM FOR THE 16K. ZX81  22-6-82 THE CODE MACHINE
10 PRINT AT 1,7;"THE CODE MACHINE"
20 PRINT
30 PRINT "PLEASE PRESS ÀcÀ TO CODE OR" ;TAB 13;"ÀdÀ TO DECODE"
40 LET A$=INKEY$ 
50 IF NOT (A$="C" OR A$="D") THEN GOTO 40 
60 CLS 
70 PRINT AT 1,3;"PLEASE INPUT CODE NUMBER";TAB 8; "(1 TO 65535)" 
80 INPUT A 
90 IF A<1 OR A>65535 THEN GOTO 80
100 CLS
110 RAND A
120 IF A$="D" THEN GOTO 1000
130 PRINT AT 1,3;"PLEASE INPUT YOUR MESSAGE";TAB 7;"( MAX. 14 LINES )"
140 INPUT B$
150 LET B=LEN B$
160 IF B<453 THEN GOTO 220
170 PRINT AT 4,3;"THIS MESSAGE IS TOO LONG" 
180 FOR F=1 TO 100
190 NEXT F
200 PRINT AT 4,3;"                      "
210 GOTO 140
220 IF B/5<>INT (B/5) THEN LET B$=B$+" "
230 IF B/5<>INT (B/5) THEN GOTO 150
240 CLS
250 PRINT "CODE ";A
260 PRINT "YOUR MESSAGE IS:-"
270 PRINT B$
280 GOSUB 2000
290 FAST
300 DIM C$(B)
310 FOR I=1 TO B
320 IF B$(I)=" " THEN LET B$(I)="." 
330 LET C=CODE B$(I)+INT(RND*26)
340 IF C>63 THEN LET C=C-37
350 LET C$(I)=CHR$ C
360 NEXT I
370 LET L=0
380 PRINT "CODE ";A
390 PRINT "THE CODE IS:-"
400 FOR I=1 TO B STEP 5
410 FOR F=0 TO 4
420 LET L=L+1
430 PRINT C$(I+F);
440 NEXT F
450 PRINT " ";
460 IF L/25=INT (L/25) THEN PRINT
470 NEXT I
480 SLOW
490 GOSUB 2000 
500 GOTO 1400
1000 PRINT AT 1,1;"PLEASE INPUT THE CODED MESSAGE"
1010 PRINT " ( MAX 18 LINES BY 25 LETTERS )"
1020 INPUT B$
1030 LET B=LEN B$
1040 IF B<577 THEN GOTO 1100
1050 PRINT AT 4,8;"THIS IS TOO LONG"
1060 FOR F=1 TO 100
1070 NEXT F
1080 PRINT AT 4,8;"               "
1090 GOTO 1020
1100 CLS
1110 PRINT "CODE ";A
1120 PRINT "CODED MESSAGE IS:-"
1130 PRINT B$
1140 GOSUB 2000
1150 FAST
1160 DIM C$(B)
1170 LET C=0
1180 FOR I=1 TO B
1190 IF B$(I)=" " THEN GOTO 1250
1200 LET C=C+1
1210 LET D=CODE B$(I)-INT (RND*26) 
1220 IF D<27 AND D<>0 THEN LET D=D+37
1230 LET C$(C)=CHR$ D
1240 IF C$(C)="." THEN LET C$(C)=" "
1250 NEXT I
1260 CLS
1270 PRINT "CODE ";A
1280 PRINT "THE MESSAGE IS:-"
1290 PRINT C$
1300 SLOW
1310 GOSUB 2000
1400 PRINT "PRESS ANY KEY TO CONTINUE"
1410 PRINT " OR ÀnewlineÀ TO STOP"
1420 LET E=CODE INKEY$
1430 IF E=0 THEN GOTO 1420
1440 CLS
1450 IF E<>118 THEN RUN
1460 STOP
2000 PRINT AT 21,0;" DO YOU WANT A COPY (Y OR N)?"
2010 LET Q$=INKEY$
2020 IF NOT (Q$="Y" OR Q$="N") THEN GOTO 2010
2030 IF Q$="N" THEN GOTO 2160
2040 PRINT AT 21,0;"   I AM MAKING A COPY FOR YOU   "
2050 LET F=0
2060 LET G=PEEK 16396+256*PEEK 16397
2070 LET G=G+1
2080 LET H=PEEK G
2090 IF H=118 THEN GOTO 2070
2100 IF H=0 THEN LET F=F+1
2110 IF H<>0 THEN LET F=0
2120 LPRINT CHR$ H;
2130 IF F<33 THEN GOTO 2070
2140 LPRINT
2150 LPRINT "--------------------------------"
2160 CLS
2170 RETURN
2200 SAVE "CODE"
2210 RUN 

CODE.P

(3.21 KiB) Downloaded 114 times

[XavSnap]

Your computer" 06/82


"Code transfer"

/Basic tools/

Contributor : XavSnap.

Code: Select all

10 INPUT X 
20 LET Y = INT (X/256) 
30 LET X =X-256*Y 
40 POKE 16388,X 
50 POKE 16389,Y 
60 NEW 
9999 SAVE "CT1"

Code: Select all

9000 FAST 
9010 LET RAMTOP = PEEK 16388+256*PEEK 16389 
9020 LET X$ ="" 
9030 LET J = 16513 
9040 LET J = J + 1 
9050 IF PEEK J =118 THEN GOTO 9080 
9060 LET X$= X$ + STR$ PEEK J+"\::" 
9070 GOTO 9040
9080 FOR J =1 TO LEN X$ 
9090 POKE RAMTOP+J,CODE X$(J) 
9100 NEXT J 
9110 STOP
9998 SAVE "CT2"
9999 RUN 9110 

Code: Select all

9000 FAST
9010 LET J=16513
9020 LET R =PEEK 16388+256*PEEK 16389
9030 LET X$=""
9040 LET R =R + 1
9050 IF PEEK R =128 THEN GOTO 9090
9060 IF PEEK R =0 THEN STOP
9070 LET X$ =X$+ CHR$ PEEK R
9080 GOTO 9040
9090 LET J =J + 1
9095 LET X =VAL X$
9100 IF PEEK J =118 THEN GOTO 9130
9110 POKE J,X
9120 GOTO 9030
9130 PRINT "INSUFFICIENT SPACE - EXTEND LINE 1 THEN GOTO 9100"
9140 STOP
9999 SAVE "CT3"

CT1.P

(1017 Bytes) Downloaded 115 times

CT2.P

(1.13 KiB) Downloaded 130 times

CT3.P

(1.21 KiB) Downloaded 119 times

[XavSnap]

"Your computer" 07/83


"DangerMan"

/Basic game/

ASM routine to peek the value at the "PRINT AT" value.

Contributor : Antipontifex.

Code: Select all

1 REM [HEX: 2A,0E,40,4E,06,0,C9 ]
10 LET LL=1 
20 LET P=PEEK 16396+256*PEEK 16397 
30 POKE 16418,1 
40 CLS
50 LET DE=0 
90 RAND 
100 LET A=20
 110 LET B=INT(RND*31) 
 130 LET A$="«««««««««««««««««««\
 «««««««««««"
 135 LET D$="...................\
 ..........."   
140 LET B$=":"
150 PRINT AT 21,0;A$;AT 20,0;D$
155 PRINT AT A,B;"*" 
160 PRINT AT 15,5;A$(TO 10);AT 15,20;A$(TO 10);AT 14,5;D$(TO 10);AT 14,20;D$(TO 10) 
170 PRINT AT 18,12;A$(TO 10);AT 17,12;D$(TO 10) 
180 PRINT AT 10,5;A$(TO 25);AT 9,5;D$(TO 25)
190 PRINT AT 5,10;A$(TO 20);AT 4,10;D$(TO 20)
200 PRINT AT 5,17;" "
210 PRINT AT 1,13;A$(TO 12);AT 0,13;D$(TO 12) 
220 LET L$="³³"
230 LET L1=5 
240 LET L2=29
250 PRINT AT L1,L2;L$ 
260 REM DRAW LADDERS
270 FOR I=10 TO 20 
280 PRINT AT I,5;B$
290 NEXT I
300 FOR I=5 TO 9
310 PRINT AT I,10;B$;AT I,17;B$
320 NEXT I 
330 FOR I=1 TO 4
340 PRINT AT I,13;B$;AT I,24;B$ 
350 NEXT I
360 FOR I=18 TO 20
370 PRINT AT I,12;B$;AT I,21;B$ 
380 NEXT I 
390 FOR I=14 TO 17
400 PRINT AT I,14;B$;AT I,19;B$
410 NEXT I
420 LET U=26
430 LET N=1 
440 IF LL=1 THEN LET S=0
450 LET W=INT(RND*10)
455 PRINT AT 22,8;"WIND:"
460 POKE P+740,W+28
700 IF RND>.4 THEN LET W=W+(INT(RND*3)-1)
705 LET W=W+(W<0)-(W>9) 
707 POKE P+740,W+28
710 PRINT AT A,B;CHR$ U; AT L1,L2;"  "
712 IF W=8 THEN LET B=B+1
715 IF W=9 THEN LET B=B+2 
720 LET L1=L1+N
730 PRINT AT L1,L2;L$
735 IF U=136 THEN LET A=A+N
740 IF L1=20 THEN LET N=-1 
750 IF L1=4 THEN LET N=1
760 LET A=A+(INKEY$="6")-(INKEY$="7") 
770 LET B=B+(INKEY$="8")-(INKEY$="5")
772 IF A<0 THEN LET A=0
774 IF B<0 THEN LET B=0 
776 IF B>31 THEN LET B=31 
780 PRINT AT A,B;
790 LET U=USR 16514
800 IF U=27 THEN LET S=S+W 
805 IF U=27 THEN LET DE=DE+1 
810 IF U=128 OR U=0 THEN GOTO 1500 
825 IF U=27 THEN LET U=26 
830 PRINT "*"
840 IF DE>100 THEN GOTO 2000
850 GOTO 700
1500 PRINT AT 21,0;"a"
1501 LET T=1
1505 FOR I=A TO 20
1510 PRINT AT I,B;"*";AT I-1,B;" "
1515 PRINT AT 21,T;"a" 
1517 LET T=T+1 
1520 NEXT I
1530 PRINT AT 20,B-3;"<<<*>>>"
1540 PRINT AT 21,B-3;"«splat«"
1550 PRINT AT 0,0;"A GRAND"
1560 PRINT "WAGE" 
1570 PRINT "OF:£";S 
1580 POKE 16418,0
1590 STOP 
2000 LET LL=LL+1
2010 PRINT "LEVEL:";LL 
2020 FOR I=1 TO 20 
2030 NEXT 
2040 GOTO 20

DANGERMAN.P

(3.13 KiB) Downloaded 112 times

[XavSnap]

Your computer" 06/82


"Drawing program"

/ASM tool/

Contributor : XavSnap.

Code: Select all

1 REM [HEX:\
3E,17,06,20,D7,\
10,FD,0E,12,D7,\
06,1E,3E,00,D7,\
10,FD,3E,17,D7,\
0D,20,F2,06,20,\
D7,10,FD,2A,0C,\
40,11,23,00,19,\
E5,CD,BB,02,7C,\
E1,44,4D,CB,47,\
C8,11,21,00,CB,\
4F,20,01,2B,CB,\
57,20,01,19,CB,\
5F,20,04,C6,00,\
ED,52,CB,67,20,\
01,23,CB,6F,20,\
13,3A,21,40,3C,\
FE,40,20,02,3E,\
80,FE,C0,20,02,\
3E,00,32,21,40,\
7E,FE,17,20,02,\
60,69,36,3D,01,\
00,05,0B,78,B1,\
20,FB,3A,21,40,\
77,01,00,10,0B,\
78,B1,20,FB,18,\
A5,76,00,14,2D ]
2 RAND USR 16514

DRAWINGPRG.P

(1.04 KiB) Downloaded 122 times

[XavSnap]

Your computer" 06/82


"Pascal Triangle"

/Basic tool/

Contributor : XavSnap.

Code: Select all

10 LET N=9
20 DIM P(N,N)
30 FOR I=1 TO N 
40 FOR J=1 TO I 
50 IF J=1 OR J=I THEN GOTO 80
60 LET P(I,J)=P(I-1,J-1)+P(I-1,J)
70 GOTO 90
80 LET P(I,J)=1
90 NEXT J 
100 NEXT I 
110 PRINT "PASCAL TRIANGLE:-"
120 PRINT 
130 FOR I=1 TO N 
140 IF I=6 THEN GOTO 170
150 PRINT TAB 14-I;
160 GOTO 180 
170 PRINT AT I+2,14-I;
180 FOR J=1 TO I
190 PRINT P(I,J);" ";
200 NEXT J
210 NEXT I
220 STOP 

PASCALTRIANGLE.P

(1.7 KiB) Downloaded 126 times

[XavSnap]

Your computer" 12/82


"Forth V.2 Simulator"

/Basic tool/

Sadly buggy...
Bad quality listing, need a second look.


Contributor : XavSnap.

Code: Select all

10 REM *********************
20 REM *FORTH SIMULATION IN*
30 REM *ZX81 BASIC R.RANSON*
40 REM *********************
50 PRINT "BASIC FORTH V.2"
60 DIM P(10)
70 DIM Q(10)
80 DIM R(10)
90 DIM S(10)
100 LET Z=300
110 REM INITIALISE
120 PRINT
130 GOTO 200
140 PRINT A$;"?"
150 GOTO 200
160 PRINT A$;"OK"
170 GOTO 220
180 PRINT "STACK EMPTY AT ";A$
190 LET S(1)=0
200 LET M=1
210 LET N=1
220 LET K=1
230 LET I$=""
240 REM
250 INPUT I$
260 LET L=0
270 LET Q(K)=L
280 LET P(K)=LEN I$
290 LET L=P(K)
300 IF N<1 THEN GOTO 180
310 LET Q(K)=Q(K)-1
320 IF Q(K)>P(K) THEN GOTO 410
330 LET B$=I$(Q(K) TO Q(K))
340 IF B$=" " THEN GOTO 310
350 LET A$=B$
360 LET Q(K)=Q(K)-1
365 IF Q(K)>P(K) THEN GOTO 460
370 LET B$=I$(Q(K) TO Q(K))
380 IF B$=" " THEN GOTO 460
390 LET A$=$A+B$
400 GOTO 360
410 IF K<2 THEN GOTO 160
420 LET K=K-1
430 LET I$=I$( TO P(K))
440 LET L=P(K)
450 GOTO 310
460 PRINT "\::";A$;
470 REM USER DEFIND DICTIONARY
500 IF A$<>"ABS" THEN GOTO 600
530 LET I$=I$+"LOOP 0 < IF -1 * THEN"
540 LET K=K+1
550 GOTO 270
600 IF A$<>"COUNT" THEN GOTO 700
630 LET I$=I$+" 0 DO CR I . LOOP"
640 LET K=K+1
650 GOTO 270
700 IF A$<>"POLY1" THEN GOTO 800
730 LET I$=I$+"LOOP DUP * + 1 -"
740 LET K=K+1
750 GOTO 270
800 IF A$<>"POLY2" THEN GOTO 900
810 GOSUB 830
820 GOTO Z
830 GOSUB 2030
840 GOSUB 2030
850 GOSUB 3230
860 GOSUB 3030
870 LET A$="1"
880 GOSUB 9040
890 GOSUB 3030
895 RETURN
1000 REM SYSTEM DICTIONARY
1100 IF A$<>"." THEN GOTO 1200
1110 GOSUB 1130
1120 GOTO Z
1130 PRINT S(N);" ";
1140 LET N=N-1
1150 RETURN
1200 IF A$<>"S?" THEN GOTO 1300
1210 GOSUB 1230
1220 GOTO Z
1230 FOR Y=0 TO N-S
1240 PRINT S(N-Y)
1250 NEXT Y
1260 RETURN
1300 IF A$<>"EMIT" THEN GOTO 1400
1310 GOSUB 1330
1320 GOTO Z
1330 PRINT CHR$ S(N);
1340 LET N=N-1
1350 RETURN
1400 IF A$<>"SPACE" THEN GOTO 1500
1410 GOSUB 1430
1420 GOTO Z
1440 PRINT " ";
1450 RETURN
1500 IF A$<>"CR" THEN GOTO 1600
1510 GOSUB 1530
1520 GOTO Z
1530 PRINT
1540 RETURN
1999 REM STACK INSTRUCTIONS
2000 IF A$<>"DUP" THEN GOTO 2100
2010 GOSUB 2030
2020 GOTO Z
2030 LET N=N+1
2040 LET S(N)=S(N-1)
2050 RETURN
2100 IF A$<>"DROP" THEN GOTO 2200
2110 GOSUB 2130
2120 GOTO Z
2130 LET N=N+1
2140 RETURN
2200 IF A$<>"SWAP" THEN GOTO 2300
2210 GOSUB 2330
2220 GOTO Z
2230 LET S(N+1)=S(N-1)
2240 LET S(N-1)=S(N)
2250 LET S(N)=S(N-1)
2260 RETURN
2300 IF A$<>"OVER" THEN GOTO 2400
2310 GOSUB 2330
2320 GOTO Z
2330 LET N=N+1
2340 LET S(N)=S(N-2)
2350 RETURN
2400 IF A$<>"I" THEN GOTO 1400
2410 GOSUB 2430
2420 GOTO Z
2430 LET N=N-1
2440 LET S(N)=R(M)
2450 RETURN
2999 REM ARITHMETIC AND LOGIC
3000 IF A$<>"+" THEN GOTO 3100
3010 GOSUB 3030
3020 GOTO Z
3030 LET N=N-1
3040 LET S(N)=S(N)+S(N+1)
3050 RETURN
3100 IF A$<>"-" THEN GOTO 3200
3110 GOSUB 3130
3120 GOTO Z
3130 LET N=N-1
3140 LET S(N)=S(N)-S(N+1)
3150 RETURN
3200 IF A$<>"*" THEN GOTO 3300
3210 GOSUB 3230
3220 GOTO Z
3230 LET N=N-1
3240 LET S(N)=S(N)*S(N+1)
3250 RETURN
3300 IF A$<>"" THEN GOTO 3400
3310 GOSUB 3330
3320 GOTO Z
3330 LET N=N-1
3340 LET S(N)=S(N)/S(N+1)
3350 RETURN
3400 IF A$<>"=" THEN GOTO 3500
3410 GOSUB 3430
3420 GOTO Z
3430 LET N=N-1
3440 LET S(N)=S(N)=S(N+1)
3450 RETURN
3500 IF A$<>"<" THEN GOTO 3600
3510 GOSUB 3530
3520 GOTO Z
3530 LET N=N-1
3540 LET S(N)=S(N)<S(N+1)
3550 RETURN
3600 IF A$<>">" THEN GOTO 3700
3610 GOSUB 3630
3620 GOTO Z
3630 LET N=N-1
3640 LET S(N)=S(N)>S(N+1)
3650 RETURN
3999 REM CONTROL INSTRUCTIONS
4000 IF A$<>"IF" THEN GOTO 4200
4030 LET N=N-1
4040 IF S(N+1) THEN GOTO Z
4050 FOR Y=Q(K) TO P(K)-3
4060 LET B$=I$(Y TO Y+3)
4070 IF B$="ELSE" THEN GOTO 4120
4080 IF B$="THEN" THEN GOTO 4120
4090 NEXT Y
4100 PRINT "ERROR IN IF"
4110 GOTO 200
4120 LET Q(K)=Y+4
4130 GOTO Z
4200 IF A$<>"ELSE" THEN GOTO 4300
4210 GOTO 4050
4300 IF A$<>"THEN" THEN GOTO 4400
4310 GOTO Z
4400 IF A$<>"DO" THEN GOTO 4500
4410 LET M=M+2
4420 LET R(M-1)=Q(K)
4430 LET R(M)=S(N-1)
4440 LET M=M+1
4450 LET R(M)=S(N)
4460 LET N=N-2
4470 GOTO Z
4500 IF A$<>"LOOP" THEN GOTO 4600
4510 LET R(M)=R(M)+1
4520 IF R(M-1)>R(M) THEN GOTO 4550
4530 LET M=M-3
4540 GOTO Z
8900 IF A$<>" STOP " THEN GOTO 9020
8910 STOP
8999 REM CONVERT TO NUMBER
9000 LET Y=CODE A$
9010 IF Y<>22 AND (Y<27 OR Y>37) THEN GOTO 140
9020 GOSUB 9040
9030 GOTO Z
9040 LET N=N+1
9050 LET S(N)=VAL A$
9060 RETURN
9999 GOTO 300

FORTHV2.P

(4.51 KiB) Downloaded 114 times

[dessony]

XavSnap,

You can find information on the bug reports article under "Your Letters" of the "Your Computer". That is how I solved a "Plane Annoying" game bug issue!


DesSony

[XavSnap]

Hi,
Yes, i ran on all over the "Your Letters" pages… But, no reports on bad quality listings…


Exemple: "ZxBug"... i don't what doing with this listing…